情報科学屋さんを目指す人のメモ（FC2ブログ版）

追記：携帯からAndroidに電話帳を移行する場合の詳細な手順を「グループ分けを保ったまま携帯のアドレス帳をAndroidへ移行する方法」にまとめました。参考にしてください。

携帯からGmailに電話帳を移行するときにグループ情報も移行できるスクリプト

スマートフォン(HTC Desire)を買ったので、携帯電話からGmailへ電話帳を移そうと思ったのですが、いくつかの方法を試してみて、グループを移行できないなどの不満がありました。それを解消するために、スクリプトを書きました。Xperiaから電話帳を移行する場合にも同じ問題があるそうなので、グループを移行したいひとは試してみてください。

今回は、スクリプトとその使い方がメインですが、携帯電話の電話帳バックアップからGmailへのインポートまでの流れをすべてまとめた記事を書く予定です。そのほかにも、大量のvCardファイルの連結について(←書いた)などの記事を書く予定です。

こんなのもうあるよーとっくにできるよーってことがあるかもしれないんですが、まぁ、せっかく書いてみたので、誰かの参考になれば幸いです。

GmailにvCardを直接インポートする問題点

vCardを変換せずに直接インポートすると、グループ分けが反映されなかったり、住所を正しくインポートしてくれなかったりします。これらを解決すべく書いたスクリプトには、次のような利点があります。

このスクリプトを使うメリット

このスクリプトには、GmailへvCard形式を読み込ませたり、Android標準(?)の連絡先アプリからインポートするのに比較して次のようなメリットがあります。

• GmailへvCardを直接インポートする場合との違い
  • 携帯電話のグループ分けを移行可能
  • ふりがなを移行（名前（フリガナ）、姓（フリガナ）両方、JBook2で読めます）
  • ふりがなに入ってしまうゴミ(；）が入らない
  • 住所をインポートし、郵便番号を先頭に配置する
  • メールアドレス・電話番号の種類を認識可能（サンプルが少ないため不完全）
  • （メリットじゃないけど、誕生日、メモも対応、GmailのvCard読み取りに負けると意味ないので）

VBScriptで作ったことで、次のようなメリットもあります。

• スクリプト実行用のツールをインストール不要（WSHはいちよまだWindowsの標準のはず）
• コードが見えるので安心
• ドラッグアンドドロップで実行可能
• カスタマイズが簡単。メモ帳で出来る。

使用上の注意

いつものことですが、自己責任でご利用ください。また、Gmailの連絡先にインポートする際には、必ずGoogle CSV形式でバックアップを取ってからインポートしてください。おねがいします。

使い方

今回は、スクリプト自体の使い方のみを説明します。携帯からGmailへの移行全体の手順についてはまた後で書くつもりです。

使うもの

今回は、vCardファイル(.vcf)をGoogle CSV形式ファイル(.csv)に変換するので、携帯電話からバックアップしたvCardファイル(.vcf)を用意してください。.vcfファイルがたくさん発生している場合の対策は次の記事に書きます。

スクリプトファイル作成

次に、実行するスクリプトファイルを作ります。作ると言っても、やることは簡単で、まず、新規のテキストファイル(.txt)を作成してください。そして、その中身に、この記事の下の方にある「スクリプト」の章にあるスクリプト自体をコピーして貼り付けてくださいコピーには、スクリプトの枠の右上に表示されるコピーボタンを使ってください。クリップボードにコピーされます

こうして、中身がスクリプトのテキストファイルを作ったら、そのファイルの名前を「vCard2GoogleCSV.vbs」というファイル名に変更してください。

ファイルの配置

「vCard」というフォルダを作成し、その中に携帯からバックアップした「vCardファイル(.vcf)」と、今作った「vCard2GoogleCSV.vbs」

スクリプト実行

スクリプトの実行は、vCardファイルをvCard2GoogleCSV.vbsのアイコンにドラッグアンドドロップするだけです。すると、ちゃんと動けば、vCardファイルの名前に「.csv」という拡張子がくっついたファイルがフォルダの中に作成されるはずです。

Google CSVファイル完成

あとは、現在のGmailの連絡先をいったんすべて削除もしものためにGoogle CSV形式でバックアップしておくこと！してから、Gmailの連絡先にインポートしてください。うまくいけば、グループが反映されるはずです。

まとめ

今回は、自分の持っているFOMA SH903iからバックアップしたvCardファイルを参考に作ったスクリプトなので、機種によっては対応していないこともあると思います。ただ、「こんなvCardの形式を投げ込んだら、こんなエラーが出た、こうダメだった」「これもバックアップしたい」と言ってくれれば、気が向く&時間がある&出来そうな範囲でスクリプトを書き直してみるかもしれません。それと、こんなソースコードを貼り付けて配布するのも珍しいかもしれないですが、まぁ、やってみてください＾＾

今回のスクリプトは、昔に作ったスクリプトを切り貼りした部分があるので、思いっきり無駄なところがあるけど気にしないでください。

スクリプト

肝心のスクリプトです。 コピーする際には、スクリプトの表示されている領域の右上に表示されるアイコンを利用することで、簡単にコピーできます（Chromeでスクリプトの表示が崩れている場合は、InternetExplorerなど、他のブラウザでの表示を試みてください）。

Option Explicit
' ##############################
'
' Global 定数
'
' ##############################
Const CSV_ROWS_MAX = 10000      ' 読み込むvCardファイルの最大"件"数
Const VCARD_LINES_MAX = 1000000 ' 読み込むvCardファイルの最大"行"数
Const MULTIPLEXED_NAME_FAMILY_NAME = True  ' 姓と名を分割できないとき姓(Family Name)にフルネームを設定する
Const MULTIPLEXED_NAME_GIVEN_NAME = False  ' 姓と名を分割できないとき名(Given Name)にフルネームを設定する

' ##############################
'
' Global 変数
'
' ##############################
Dim Key ' Google CSV's Key
Dim Key2Index ' Google CSV's Key to ArrayIndex


' ##############################
'
' 実行
'
' ##############################
Dim ErrorMessage : ErrorMessage = ""
If(Not CheckConfig(ErrorMessage)) Then
  WScript.Echo "エラーメッセージ：" & vbCrLf & ErrorMessage & vbCrLf & vbCrLf & "スクリプトの実行を中止します。"
  WScript.Quit
End If
Call InitializeKey()
Call Main()

' ##############################
'
' 設定（定数）の確認
'
' ##############################
Function CheckConfig(ByRef ErrorMessage)
  CheckConfig = True
  Dim Message : Message = ""
  
  If NOT(MULTIPLEXED_NAME_FAMILY_NAME OR MULTIPLEXED_NAME_GIVEN_NAME) Then
    CheckConfig = False
    ErrorMessage = "MULTIPLEXED_NAME_FAMILY_NAME と MULTIPLEXED_NAME_GIVEN_NAME は少なくとも一方をTrueにしてください。"
  End If
 
End Function

' ##############################
'
' Google CSV 構造準備
'
' ##############################
Sub InitializeKey()
  ' Phone Type = Mobile/Home/Work
  ' Birthday = YYYY-MM-DD
  Key = Array( _
  "Name", _
  "Given Name", _
  "Additional Name", _
  "Family Name", _
  "Yomi Name", _
  "Given Name Yomi", _
  "Additional Name Yomi", _
  "Family Name Yomi", _
  "Group Membership", _
  "Phone 1 - Type", _
  "Phone 1 - Value", _
  "Phone 2 - Type", _
  "Phone 2 - Value", _
  "Phone 3 - Type", _
  "Phone 3 - Value", _
  "E-mail 1 - Type", _
  "E-mail 1 - Value", _
  "E-mail 2 - Type", _
  "E-mail 2 - Value", _
  "E-mail 3 - Type", _
  "E-mail 3 - Value", _
  "Address 1 - Formatted", _
  "Address 2 - Formatted", _
  "Address 3 - Formatted", _
  "Birthday", _
  "Notes")

  Set Key2Index = CreateObject("Scripting.Dictionary")
  Dim i
  For i = 0 To UBound(Key)
    Key2Index.Add Key(i), i
  Next
End Sub

' ##############################
'
' Main
'
' ##############################
Sub Main()

Dim i : i = 0
Dim j : j = 0

Dim fso : Set fso = CreateObject("Scripting.FileSystemObject")
Dim strFilePath : strFilePath = GetArg()
Dim strFileName : strFileName = fso.GetFileName(strFilePath)

' ==============================
' vCard 読込
' ==============================
Dim strLines() : ReDim strLines(VCARD_LINES_MAX)
If IsEmpty(strFilePath) Then
  Exit Sub ' 終了
Else
  Call ReadLine(strLines, strFilePath)
End If

' ==============================
' vCard -> CSV 変換処理
' ==============================
Dim CSVRows() : ReDim CSVRows(CSV_ROWS_MAX)
Dim nRow : nRow  = 0
Dim intLineNum : intLineNum = 0
Do While intLineNum <= UBound(strLines)
  If Trim(strLines(intLineNum)) = "BEGIN:VCARD" Then
    ' ==============================
    ' ▼ 一人分の vCard の読込 ▼
    ' ==============================
    Dim Row ' CSV Row
    ReDim Row(UBound(Key))
    For j = 0 To UBound(Row)
      Row(j) = ""
    Next
    Dim nPhone : nPhone = 0 ' 1つのvCardに出てきた TEL の数
    Dim nEMail : nEMail = 0 ' 1つのvCardに出てきた EMAIL の数
    Dim nAddress : nAddress = 0 ' 1つのvCardに出てきた ADR の数
    Dim nVCardLines : nVCardLines = 0 ' 1つのvCardの読み込んだ行数
    Do While True
      ' ==============================
      ' ▼ 1つの プロパティ の読込 ▼
      ' ==============================
      Dim DC : DC = Split(strLines(intLineNum),":")  'DividedByCologne
        ' Quoted Printable 無視
        If InStr(1, strLines(intLineNum), "QUOTED") > 0 Then
          DC = Split("DUMMY:DUMMY",":")  ' Dummy Property
        End If
        If UBound(DC) < 1 Then
          ' WScript.Echo "ERROR : InvalidInput" & vbCrLf & "LINE_NUM : " & intLineNum & vbCrLf & "LINE : " & strLines(intLineNum)
          ' WScript.Echo intLineNum & "行目に、コロン(:)がありません。確認してください。" & vbCrLf & "プログラムを終了します。"
          ' Exit Sub
          DC = Split("DUMMY:DUMMY",":")  ' Dummy Property
        Else
          For i = 2 To Ubound(DC)
            DC(1) = DC(1) & ":" & DC(i)
            ' WScript.Echo intLineNum & ":" & DC(1)
          Next
        End If
      Dim BC : BC = DC(0) 'BeforeCologne
      Dim AC : AC = DC(1) 'AfterCologne
      Dim BCSS : BCSS = Split(BC, ";") 'BeforeCologne Splited by Semicolon
      Dim ACSS : ACSS = Split(AC, ";") 'AfterCologne Splited by Semicolon
      Dim strType : strType = ""
      
      If AC = "" Then
        ' 値のないプロパティを飛ばす
      ElseIf BC = "" Then
        ' 「:」で始まる行を飛ばす
        ' WScript.Echo strLines(intLineNum)
      Else    
        Select Case BCSS(0)
        ' ==============================
        Case "BEGIN" ' VCARDの開始
          
        ' ==============================
        Case "FN" ' フルネーム?
          If GetInfo("Name", Row) = "" Then
            Dim strFullName : strFullName = Replace(AC, ";", "")

            Call AddInfo("Name", Trim(strFullName), Row)
            If(MULTIPLEXED_NAME_GIVEN_NAME) Then Call AddInfo("Given Name", Trim(strFullName), Row)
            If(MULTIPLEXED_NAME_FAMILY_NAME) Then Call AddInfo("Family Name", Trim(strFullName), Row)
          End If
        ' ==============================
        Case "N" ' 名前
          Dim strRawName : strRawName = Replace(AC, ";", "")

          Dim strName : strName = strRawName ' 姓名
          Dim strFamilyName : strFamilyName= "" ' 姓
          If(MULTIPLEXED_NAME_FAMILY_NAME) Then strFamilyName = strRawName
          Dim strGivenName : strGivenName = ""' 名
          If(MULTIPLEXED_NAME_GIVEN_NAME) Then strGivenName = strRawName

          Dim SSName : SSName = Split(AC, ";")  ' SemicolonSplitedName
          If(UBound(SSName) > 0) Then
            If(Len(SSName(0)) > 0 And Len(SSName(1)) > 0) Then
              ' 姓名の判別が可能な場合は再設定
              strName = SSName(0) & SSName(1)
              strFamilyName = SSName(0)
              strGivenName = SSName(1)
            End If
          End If

          Call AddInfo("Name", Trim(strName), Row)
          Call AddInfo("Given Name", Trim(strGivenName), Row)
          Call AddInfo("Family Name", Trim(strFamilyName), Row)
        ' ==============================
        Case "SOUND", "SORT-STRING" ' ふりがな
          Dim WAC : WAC = ConvToWideKatakana(AC)
          Dim strYomiName
          Dim strFamilyNameYomi
          Dim strGivenNameYomi
          Dim SplitFamilyAndGiven : SplitFamilyAndGiven = True
          If SplitFamilyAndGiven Then
            Dim SSSound : SSSound = Split(WAC, ";") ' SemicolonSplitedSound
            If(Ubound(SSSound) = 0) Then
              strYomiName = Replace(WAC, ";", "")
              strFamilyNameYomi = Replace(WAC, ";", "")
              strGivenNameYomi = ""
            ElseIf(Len(SSSound(1)) > 0) Then
              strYomiName = SSSound(0) & SSSound(1)
              strFamilyNameYomi = SSSound(0)
              strGivenNameYomi = SSSound(1)
            Else
              strYomiName = Replace(WAC, ";", "")
              strFamilyNameYomi = Replace(WAC, ";", "")
              strGivenNameYomi = ""
            End If
          Else
            strYomiName = Replace(WAC, ";", "")
            strFamilyNameYomi = Replace(WAC, ";", "")
            strGivenNameYomi = ""
          End If
          Call AddInfo("Yomi Name", Trim(strYomiName), Row)
          Call AddInfo("Given Name Yomi", Trim(strGivenNameYomi), Row)
          Call AddInfo("Family Name Yomi", Trim(strFamilyNameYomi), Row)
        ' ==============================
        Case "EMAIL" ' メールアドレス
          If nEMail < 3 Then
            nEMail = nEMail + 1 
            If InStr(1, BC, ";") > 0 Then
              strType = Split(BC, ";")(UBound(Split(BC,";")))
              If InStr(1, strType, "=") > 0 Then
                strType = Mid(strType, InStr(1, strType, "=") + 1)
              End If
              
              Select Case strType
              Case "INTERNET" : strType = "Home"
              Case "CELL"     : strType = "Other"
              Case "WORK"     : strType = "Work"
              End Select
            Else
              strType = ""
            End If
            Call AddInfo("E-mail " & nEMail & " - Type", strType, Row)
            Call AddInfo("E-mail " & nEMail & " - Value", AC, Row)
          End If
        ' ==============================
        Case "TEL" ' 電話番号
          If nPhone < 3 Then
            nPhone = nPhone + 1
            If UBOUND(BCSS) > 0 Then
              Select Case BCSS(1)
              Case "CELL" ' 携帯電話
                strType = "Mobile"
              Case "VOICE" ' 家の電話
                strType = "Home"
              Case "WORK" ' 会社の電話
                strType = "Work"
              End Select
              Call AddInfo("Phone " & nPhone & " - Type", strType, Row)
            End If
            Call AddInfo("Phone " & nPhone & " - Value", AC, Row) 
          End If
        ' ==============================
        Case "X-GN" ' グループ
          Call AddInfo("Group Membership", AC, Row)
        ' ==============================
        Case "ADR" ' 住所
          If nAddress < 3 Then
            If UBOUND(ACSS) < 5 Then
              Call AddInfo("Address " & nAddress & " - Formatted", Replace(AC,";",""), Row)
            Else
              nAddress = nAddress + 1
              Dim strAdr : strAdr = Split(AC, ";")(1) ' 住所
              Dim strZip : strZip = Split(AC, ";")(5) ' 郵便番号
              If (strZip = "") Or (Len(strZip) <> 7) Then
                Call AddInfo("Address " & nAddress & " - Formatted", strAdr, Row)
              Else
                strZip = Mid(strZip, 1, 3) + "-" + Mid(strZip, 4)
                Call AddInfo("Address " & nAddress & " - Formatted", strZip & " " & strAdr, Row)
              End If
            End If
          End If
        ' ==============================
        Case "BDAY"  ' 誕生日
          Dim strBirthday
          If Len(AC) = 8 Then ' YYYYMMDD
            strBirthday = Mid(AC, 1, 4) & "-" & Mid(AC, 5, 2) & "-" & Mid(AC, 7, 2)
          ElseIf Len(AC) = 10 Then ' YYYY-MM-DD
            strBirthday = AC
          Else
            strBirthday = AC
          End If
          Call AddInfo("Birthday", strBirthday, Row)
        ' ==============================
        Case "NOTE" ' メモ
          Call AddInfo("Notes", AC, Row)
        ' ==============================
        Case "END" ' END:VCARD
          Exit Do
        ' ==============================
        End Select
      End If
      
      
      intLineNum = intLineNum + 1
      nVCardLines = nVCardLines + 1
      
      If nVCardLines > VCARD_LINES_MAX Then
        WScript.Echo "Over " & VCARD_LINES_MAX & " Lines in a single vCard (line:" & intLineNum & ")"
        Exit Sub
      End If
      ' ==============================
      ' ▲ 1つの プロパティ の読込 ▲
      ' ==============================
    Loop
    
    CSVRows(nRow) = Row
    nRow = nRow + 1
    ' ==============================
    ' ▲ 一人分の vCard の読込 ▲
    ' ==============================        
  End If
  intLineNum = intLineNum + 1
Loop


' ==============================
' CSV データ構築
' ==============================
ReDim Preserve CSVRows(nRow - 1)
Dim strOutput() : ReDim strOutput(1 + UBound(CSVRows))
For i = 0 To UBound(strOutput)
  strOutput(i) = ""
Next

' 1行目
For i = 0 To UBound(Key)
  strOutput(0) = strOutput(0) & Key(i) & ","
Next

' 2行目以降
Dim bln
For i = 1 To UBound(strOutput)
  For j = 0 To UBound(Key)
    Dim strValue : strValue = CSVRows(i - 1)(j)
    Dim blnEscaped : blnEscaped = False
    If InStr(1, strValue, """") Then
      strValue = Replace(strValue, """", """""") ' 「"」を「""」に
      blnEscaped = True
    End If
    If InStr(1, strValue, ",") Then
      blnEscaped = True
    End If
    If blnEscaped Then
      strValue = """" & strValue & """"
    End If
    strOutput(i) = strOutput(i) & strValue & ","
  Next
Next

' ==============================
' CSV データ書き出し
' ==============================
Call InputTextFile(strOutput, strFileName & ".csv")

End Sub ' Main()

' ##############################
'
'CSVの行に情報を入力する
'
' ##############################
Sub AddInfo(ByVal strKey, ByVal strValue, ByRef strRow())
  strRow(Key2Index.Item(strKey)) = strValue
End Sub


' ##############################
'
'CSVの行から情報を取り出す
'
' ##############################
Function GetInfo(ByVal strKey, ByRef strRow())
  GetInfo = strRow(Key2Index.Item(strKey))
End Function

' ##############################
'
'ファイルを１行ずつ配列へ入力
'
' ##############################
Sub ReadLine(ByRef strLineArray(), ByVal strFilePath)

Const ForReading = 1  '読み込み

Dim objFileSys : Set objFileSys = CreateObject("Scripting.FileSystemObject")
Dim objInFile : Set objInFile = objFileSys.OpenTextFile(strFilePath, ForReading)

If Err.Number=0 Then
  'ファイルを最後までループ
  Dim strLine : strLine = ""
  Dim i : i = 0
  Do Until objInFile.AtEndOfStream = True
    'ファイルを１行ずつ読み込む
    strLine = objInFile.ReadLine
    If Left(strLine, 1) = " " Then
      ' 前の行の続き
      strLineArray(i - 1) = strLineArray(i - 1) & Mid(strLine, 2)
    Else
      strLineArray(i) = strLine
      i = i + 1
    End If
  Loop
  objInFile.Close

  '配列のサイズを再宣言
  ReDim Preserve strLineArray(i)
Else
  'ファイルの読み込みに失敗した場合
  ReDim Preserve strLineArray(0)
End If

'オブジェクトを廃棄
Set objFileSys = Nothing
Set objInFile = Nothing

End Sub

' ##############################
'
'パラメーターを読み込む
'
' ##############################
Function GetArg()

Dim objArg : Set objArg = Wscript.Arguments

If objArg.Count = 0 Then
  WScript.echo "対象ファイルをドラッグアンドドロップしてください。"
  GetArg = Empty
ElseIf objArg.Count > 1 Then
  WScript.echo "対象とできるファイルは１つのみです。"
  GetArg = Empty
Else
  GetArg = objArg(0)
End If

End Function

' ##############################
'
'新規テキストに、配列の中身を書き込む
'
' ##############################
Function InputTextFile(ByVal strLineArray, ByVal strNewFileName)

Const ForAppending = 8  '追記モード

Dim objFileSys : Set objFileSys = CreateObject("Scripting.FileSystemObject")
Dim strScriptPath : strScriptPath = Replace(WScript.ScriptFullName, WScript.ScriptName, "")
Dim strCreateFile : strCreateFile = objFileSys.BuildPath(strScriptPath, strNewFileName)
objFileSys.CreateTextFile strCreateFile
Dim objNewFile : Set objNewFile = objFileSys.OpenTextFile(strCreateFile, ForAppending)

Dim counter
For counter = 0 To UBound(strLineArray)
  objNewFile.WriteLine strLineArray(counter)
Next
objNewFile.Close

'オブジェクトを破棄
Set objFileSys = Nothing
Set objNewFile = Nothing
End Function

' ##############################
'
'半角カタカナを全角カタカナに変換する
'
' ##############################
Function ConvToWideKatakana(ByVal strTarget) ' As String
Dim strTemp : strTemp = strTarget
Dim strHanKatakana : strHanKatakana = Array("ｧ", "ｱ", "ｨ", "ｲ", "ｩ", "ｳ", "ｪ", "ｴ", "ｫ", "ｵ", "ｶ", "ｶﾞ", "ｷ", "ｷﾞ", "ｸ", "ｸﾞ", "ｹ", "ｹﾞ", "ｺ", "ｺﾞ", "ｻ", "ｻﾞ", "ｼ", "ｼﾞ", "ｽ", "ｽﾞ", "ｾ", "ｾﾞ", "ｿ", "ｿﾞ", "ﾀ", "ﾀﾞ", "ﾁ", "ﾁﾞ", "ｯ", "ﾂ", "ﾂﾞ", "ﾃ", "ﾃﾞ", "ﾄ", "ﾄﾞ", "ﾅ", "ﾆ", "ﾇ", "ﾈ", "ﾉ", "ﾊ", "ﾊﾞ", "ﾊﾟ", "ﾋ", "ﾋﾞ", "ﾋﾟ", "ﾌ", "ﾌﾞ", "ﾌﾟ", "ﾍ", "ﾍﾞ", "ﾍﾟ", "ﾎ", "ﾎﾞ", "ﾎﾟ", "ﾏ", "ﾐ", "ﾑ", "ﾒ", "ﾓ", "ｬ", "ﾔ", "ｭ", "ﾕ", "ｮ", "ﾖ", "ﾗ", "ﾘ", "ﾙ", "ﾚ", "ﾛ", "ﾜ", "ｦ", "ﾝ")
Dim strZenKatakana : strZenKatakana = Array("ァ", "ア", "ィ", "イ", "ゥ", "ウ", "ェ", "エ", "ォ", "オ", "カ", "ガ", "キ", "ギ", "ク", "グ", "ケ", "ゲ", "コ", "ゴ", "サ", "ザ", "シ", "ジ", "ス", "ズ", "セ", "ゼ", "ソ", "ゾ", "タ", "ダ", "チ", "ヂ", "ッ", "ツ", "ヅ", "テ", "デ", "ト", "ド", "ナ", "ニ", "ヌ", "ネ", "ノ", "ハ", "バ", "パ", "ヒ", "ビ", "ピ", "フ", "ブ", "プ", "ヘ", "ベ", "ペ", "ホ", "ボ", "ポ", "マ", "ミ", "ム", "メ", "モ", "ャ", "ヤ", "ュ", "ユ", "ョ", "ヨ", "ラ", "リ", "ル", "レ", "ロ", "ワ", "ヲ", "ン")
Dim i
For i = UBound(strHanKatakana) To 0 Step -1
  strTemp = Replace(strTemp, strHanKatakana(i), strZenKatakana(i))
Next
ConvToWideKatakana = strTemp
End Function

こんなところまで読んでくださりありがとうございます。もしよろしければコメントか@did2memoにtweetを。vCardサンプル（BIGIN:VCARDからEND:VCARDまで一人分、個人情報に注意）や、使えなかったよ情報を貼り付けていただければ、対応できるかもしれません。あ、そんなじゃなくても、コメント大歓迎です。

更新履歴

• 2010.05.23 コメント修正
• 2010.05.23 大きなvCardに対する制限を20行から100行へ拡大
• 2010.07.14 コロンのない行を発見したときに報告するように変更
• 2010.07.14 データにコロンが含まれていた場合に対処
• 2010.07.16 quoted-printableエンコードのプロパティを無視して続行するように変更
• 2010.07.16 行数の100行制限を10万行制限に変更
• 2010.09.01 住所の形式が想定外の場合に対応
• 2010.09.01 行の前後のスペースを無視するように変更
• 2011.02.14
  • 半角カタカナのふりがなを全角カタカナに変換するようにした。
  • 名前の姓名が分離できるときは分離するようにした。
  • ふりがなの姓名が分離できるときは分離するようにした。
  • 名前の末尾に含まれるスペースを削除するようにした。
• 2010.02.23 一人分のvCardの制限を100行から1万行へ変更
• 2011.03.30 コロンで始まる行を無視するようにした
• 2011.04.09 SORT-STRINGラベルもふりがなとして認識するようにした
• 2011.05.28
  • 「N」の行にセミコロンが一つもない場合に対応
  • 「N」が存在せず、「FN」のみが存在する場合に対応。ただし、「FN」より「N」を優先する。
• 2011.07.15
  • 「ADR」の行のセミコロンの数が間違っていても、住所として取り込めるようにした
  • 行数の100行制限を10万行制限に変更
• 2011.07.26
  • マジックナンバーを、定数変数化した
  • 電話帳の件数の上限を１万件にした
  • 行数の制限を100万件にした
• 2012.01.09
  • １件目を飛ばしてしまうバグを修正
  • 名前が二重になってしまって困る指摘が多かったため、名前を二重するかどうかを簡単に設定できるようにした。MULTIPLEXED_NAME_FAMILY_NAMEとMULTIPLEXED_NAME_GIVEN_NAMEを両方Trueにすると名前が二重になり、片方だけTrueにすると、二重にならなくなる。デフォルトはMULTIPLEXED_NAME_FAMILY_NAMEのみTrueで、二重にならない設定
  • 設定の間違いを検出するコード（CheckConfig）を追加